.title print verb name

; VERB Version 1.0 June 1st, 1985
; Written  by Joe Meadows Jr.,  with thanks  to the
; Fred Hutchinson Cancer Research Center for kindly
; allowing  me to  use  their  computing  resources.
;
; If  you  have any  questions, comments, ideas, or
; whatever, feel free to contact me via US Mail :
;	Joe Meadows Jr.
;	4841 268th Ave. N.E.
;	Redmond Wa. 98052
; or via phone : (206) 827-7296

	.library 'clexlib'

	.entry	clex_print_verb,^m<r2,r3,r4,r5,r6,r7>
	; 4(ap) = address of command block

	movl	4(ap),r6
	movzwl	cmd_w_name(r6),r7
	addl	r6,r7
	case	cmd_b_subtype(r6),type=b,limit=#1,<-
		_verb,-
		_syntax>

	movl	#0,r0	; invalid
	ret

_verb:	movzbl	(r7),r2	; save size of entire thing
	movzbl	1(r7),r3	; save size of verb name
_verb1:	incl	r7	; point to first ascic
	add_ascic_trunc	r7,r3
	decl	r2	; subtract off extra byte for count byte

	movzbl	(r7),r4	; assume verb bigger than synonym
	cmpb	(r7),r3	; is synonym bigger than verb?
	bleq	_verb2
	movzbl	r3,r4	; if so it got truncated by CDU
	add_string	<' (synonym truncated)'>
_verb2:	subb	r4,r2	; subtract off printed portion.
	beql	_verb3

	addl	r4,r7
	tstb	1(r7)
	beql	_verb1	; if zero length string , skip to next.
	add_string	<' , '>
	brb	_verb1
_verb3:	brb	_continue

_syntax:
	add_string	<'(syntax) '>
	add_ascic	r7

_continue:
	calls	#0,put_output

	ret

	.entry	clex_get_verb_name,^m<r2,r3,r4,r5,r6,r7>
	; 4(ap) = address of command block

	movl	4(ap),r6
	movzwl	cmd_w_name(r6),r7
	addl	r6,r7
	case	cmd_b_subtype(r6),type=b,limit=#1,<-
		_get_verb>
	movl	#0,r0	; invalid
	ret

_get_verb:
	movzbl	(r7),r2	; save size of entire thing
	movzbl	1(r7),r3	; save size of verb name
	incl	r7	; point to first ascic
	add_ascic_trunc	r7,r3

	pushaq	_clex_desc
	pushl	8(ap)
	calls	#2,g^str$copy_dx
	movl	_clex_pos,@12(ap)
	clrl	_clex_pos

	ret

	.end