.title	initialization routines

; VERB Version 1.0 June 1st, 1985
; Written  by Joe Meadows Jr.,  with thanks  to the
; Fred Hutchinson Cancer Research Center for kindly
; allowing  me to  use  their  computing  resources.
;
; If  you  have any  questions, comments, ideas, or
; whatever, feel free to contact me via US Mail :
;	Joe Meadows Jr.
;	4841 268th Ave. N.E.
;	Redmond Wa. 98052
; or via phone : (206) 827-7296

	.library	'clexlib'

	.psect	_clex_common	rd,wrt,noexe
clex_table::	.long	; table address
clex_verbs::	.long	; verb list
clex_commands::	.long	; command list
clex_cmd_cnt::	.long	; number of verbs
clex_output::	.long	; output routine address
clex_width::	.long	; width of output buffer
_clex_handler_flag::
	.long
_clex_cmd_block::
	.long

	.sbttl	initialize table address

	.psect	_clex_code	rd,nowrt,exe

	.entry	clex_use_process_table,0
	; ret-status = clex_use_process_table()
	movl	ctl$ag_clitable,clex_table
	jsb	_clex_initialize
	ret

	.entry clex_use_image,0
	; ret-status = clex_use_image (tableaddress)
	movl	@4(ap),clex_table
	jsb	_clex_initialize
	ret

	.psect	_clex_local	rd,wrt,noexe
fab:	$fab	dnm=<SYS$SHARE:DCLTABLES.EXE>,fac=get,fop=ufo
inadr:	.long	^x200,^x200
retadr:	.quad
$secdef

	.psect	_clex_code	rd,nowrt,exe

	.entry	clex_use_command_table,0
	; ret-status = clex_use_command_table( table )
	movl	4(ap),r0
	movb	(r0),fab+fab$b_fns
	movl	4(r0),fab+fab$l_fna
	$open	fab=fab
	blbc	r0,10$
	$crmpsc_s -
		inadr=inadr,retadr=retadr,flags=#<sec$m_expreg>,-
		chan=fab+fab$l_stv,vbn=#2
	blbc	r0,10$
	movl	retadr,clex_table	
	jsb	_clex_initialize
10$:	ret

_clex_initialize:
	movl	clex_table,r0
	addl3	r0,vec_l_verbtbl(r0),clex_verbs
	addl3	r0,vec_l_comdptr(r0),r1
	movzwl	vec_w_tro_count(r1),clex_cmd_cnt
	addl	#8,clex_verbs
	addl3	#8,r1,clex_commands
	movl	#1,r0
	rsb

	.entry	clex_init_output,0
	movl	4(ap),clex_output
	movl	@8(ap),clex_width
	ret

	.end