.title evaluate entity, to print out TYPEs and SYNTAX's

; VERB Version 1.0 June 1st, 1985
; Written  by Joe Meadows Jr.,  with thanks  to the
; Fred Hutchinson Cancer Research Center for kindly
; allowing  me to  use  their  computing  resources.
;
; If  you  have any  questions, comments, ideas, or
; whatever, feel free to contact me via US Mail :
;	Joe Meadows Jr.
;	4841 268th Ave. N.E.
;	Redmond Wa. 98052
; or via phone : (206) 827-7296

	.psect	_clex_local	rd,wrt,noexe
_clex_eval_count::
	.long
_clex_evals::
	.blkl	4096
_clex_ents_count::
	.long
_clex_ents::
	.blkl	4096

	.psect	_clex_code	rd,nowrt,exe

	.entry	clex_evaluate_entity,^m<r2,r3,r4,r5>

	movl	4(ap),r2
	moval	_clex_evals,r3

_evaluate:
	tstl	ent_l_user_type(r2)
	beql	10$
	addl3	clex_table,ent_l_user_type(r2),r4
	addl3	type_l_keywords(r4),clex_table,r4

	clrl	r1
	tstl	_clex_eval_count
	beql	5$
3$:	cmpl	r4,(r3)[r1]
	beql	10$
	aoblss	_clex_eval_count,r1,3$

5$:	movl	r4,(r3)[r1]
	incl	_clex_eval_count

	pushl	r4
	calls	#1,clex_evaluate_entity

	addl3	clex_table,ent_l_user_type(r2),-(sp)
	calls	#1,clex_print_type

10$:	tstl	ent_l_syntax(r2)
	beql	20$
	addl3	clex_table,ent_l_syntax(r2),r4

	clrl	r1
	tstl	_clex_eval_count
	beql	15$
13$:	cmpl	r4,(r3)[r1]
	beql	20$
	aoblss	_clex_eval_count,r1,13$

15$:	movl	r4,(r3)[r1]
	incl	_clex_eval_count
	pushl	r4
	calls	#1,clex_print_command

20$:	tstl	ent_l_next(r2)
	beql	30$
	addl3	clex_table,ent_l_next(r2),-(sp)
	calls	#1,clex_evaluate_entity

30$:	ret
	.end