.title	macro routines

; VERB Version 1.0 June 1st, 1985
; Written  by Joe Meadows Jr.,  with thanks  to the
; Fred Hutchinson Cancer Research Center for kindly
; allowing  me to  use  their  computing  resources.
;
; If  you  have any  questions, comments, ideas, or
; whatever, feel free to contact me via US Mail :
;	Joe Meadows Jr.
;	4841 268th Ave. N.E.
;	Redmond Wa. 98052
; or via phone : (206) 827-7296

	.macro	add_ascic,thing
	pushl	thing
	calls	#1,g^add_to_buffer
	.endm	add_ascic
	.macro	add_ascic_trunc,thing,leng,?l1,?l2
	pushl	leng
	pushl	thing
	calls	#2,g^add_to_buffer_trunc
	.endm	add_ascic_trunc
	.macro	add_string,thing
	push_string	<thing>
	calls	#1,g^add_to_buffer
	.endm	add_string

	.macro	case,src,displist,type=w,limit=#0,nmode=s^#,?base,?max
	case'type	src,limit,nmode'<<max-base>/2-1>
base:
	.irp	ep,<displist>
	.word	ep-base
	.endr
max:
	.endm	case

	.macro	push_string	text,?l1,?l2
	.save
	.psect	_clex$strings,exe,nowrt,pic
l1:	.ascic	text
	.restore
	pushal	l1
	.endm	push_string

	.macro	string	text,?l1,?l2
	.save
	.psect	_clex$strings,exe,nowrt,pic
l1:	.ascic	text
	.restore
	.long	l1
	.endm	string