DELETE HISTO_Y;
REDEFINE PLOT HISTO_Y				! changed from X_Y
DECLARE X_AXIS, Y_AXIS, X_LENGTH, Y_LENGTH, X_MAX, X_MIN, Y_MIN, Y_MAX
DECLARE X_POS, Y_POS, I,  PLOT_LIMITS_Y
DECLARE VECTOR XS, YS
DECLARE STRING X_LABEL, Y_LABEL
ENTRY 0 (X_LBL : STRING)
    BEGIN
	PLOT DATA_LIMITS 0
	X_LABEL = X_LBL
	Y_LABEL = 'Frequency'			! changed
	X_AXIS = 100
	Y_AXIS = 360
    END
ENTRY 1 (X : REAL : "values")			! changed
    BEGIN
	i = SEARCH (X, XS)			! added
	IF i EQ 0				! added
	    BEGIN				! added
		i = SIZE (XS) + 1		! added
		XS (i) = X			! changed
	    END					! added
	YS (i) = YS (i) + 1			! changed
    END
! Print scatter plot				! no changes from here on
ENTRY 2
    BEGIN
	PLOT HOUSEKEEP 0
    	SET_SEGMENT 1
	PLOT DATA_LIMITS 2 (X_LENGTH, Y_LENGTH)
	PLOT DATA_LIMITS 5 (XS, YS)
	PLOT LABEL 0 (X_AXIS, Y_AXIS, X_LENGTH, Y_LENGTH, X_LABEL, Y_LABEL)
	PLOT DIMENSIONS 13 (Y_MIN, Y_MAX, YS, XS)
	IF SIZE (YS) NE 0
	   THEN PLOT DIMENSIONS 3 (X_MIN, X_MAX, Y_MIN, Y_MAX, XS, YS)
	   ELSE
	      BEGIN
		  X_MIN = 0
	          X_MAX = 0
	      END
	PLOT DIMENSIONS 6 (PLOT_LIMITS_Y)
	IF PLOT_LIMITS_Y EQ 0 THEN
	   IF Y_MIN > 0
	      THEN Y_MIN = 0
	PLOT LABEL 2 (X_MIN, X_MAX, XS)
	PLOT LABEL 3 (Y_MIN, Y_MAX)
	PLOT LABEL 8 (YS)
	INCR I OVER XS
	    PRINT CENTER (XS(I), YS(I)-9, '+', 9)
    	OUTPUT_SEGMENT 1
	PLOT HOUSEKEEP 2
    END
END_PLOT